6000 PRINT"[147]"
6010 POKE53280,14:POKE646,14:POKE53281,6
6020 A=A+1
6025 IFA=1THENLOAD"PARSER CODE",8,1
7000 REM   BASIC PARSE CALL
7010 PA=50018:REM SET PA="WDPTRA"
7020 MO=50065:REM SET MO="MORE"
7030 SM=50066:REM SET SM="SAMORE"
7040 BF=50076:REM SET BF="INBUFF"
7050 LS=50075:REM SET LS="LSBUFF"
7060 OU=50040:REM SET OU="VERB"
7070 DEF FN P(X)=PEEK (OU+X)
7080 A$="":INPUT A$
7090 IF LEN (A$)=0 THEN GOTO 7130
7100 FOR I=1 TO LEN (A$)
7110 : POKE BF+I-1,ASC (MID$(A$,I,1))
7120 NEXT I
7130 POKE LS,LEN (A$)
7140 POKE PA,0:POKE MO,0:POKE SM,0
7150 SYS 49152
7160 IF FNP(2)>=5AND FNP(22)=0AND FNP(17)<>0THEN POKE OU+22,FNP(2):POKE OU+2,0
7170 SYS 49161
7180 REM             PRINT OUTPUT
7190 PRINT:PRINT "ACTION  :";FNP(31);"VERB";FNP(0);FNP(1);"VERS";FNP(2);FNP(3)
7200 FOR I=0 TO 2
7210 PRINT "OBJECT";CHR$(49+I);" :";FNP(32+I);"N";FNP(16+I);FNP(19+I);
7220 PRINT "A";FNP(10+I);FNP(13+I);"O";FNP(4+I);FNP(7+I)
7230 NEXT I
7240 PRINT "PREPOSIT:";FNP(22);FNP(23)
7250 PRINT "SAY VERB:";FNP(27);FNP(28)
7260 PRINT "SAY PREP:";FNP(29);FNP(30)
7270 PRINT "SAY MORE:";FNP(26)
7280 PRINT "MORE    :";FNP(25)
7290 PRINT "ERROR   :";FNP(24)
7300 IF FNP(24)=0 THEN GOTO 7340
7310 PRINT "I GOT STUCK AT ";:SYS 49155
7320 PRINT
7330 REM ARE ALL OBJECTS RECOGNIZED
7340 FOR I=0 TO 2
7350 IF FNP(32+I)<>255 THEN GOTO 7410
7360 PRINT "I DON'T KNOW WHAT A ";
7370 POKE PA,3:POKE PA+1,FNP(13+I)
7380 SYS 49158:PRINT " ";
7390 POKE PA,2:POKE PA+1,FNP(19+I)
7400 SYS 49158:PRINT " IS."
7410 NEXT I
7420 REM IS THE ACTION RECOGNIZED
7430 IF FNP (31)<>255 THEN GOTO 7500
7440 PRINT "[201] DON'T KNOW HOW TO ";
7450 POKE PA,0:POKE PA+1,FNP(1)
7460 SYS 49158:PRINT " ";
7470 POKE PA,1:POKE PA+1,FNP(3)
7480 SYS 49158:PRINT "."
7490 :
7500 REM ALL OUTPUT DONE
7510 PRINT
7520 IF PEEK (MO)=0 THEN GOTO 7080
7530 PRINT "PRESS SPACE FOR NEXT LIST"
7540 GET A$:IF A$<>" "THEN 7540
7550 GOTO 7150